DAQ Arduino with NodeJS serialport

In this tutorial, I will make a Data Acquisition (DAQ) procedure between PC and Arduino. PC (with NodeJS) will send command to Arduino via serialport, then Arduino will send response to PC so that PC can plot the data.

At code line of Arduino, I make the main loop do nothing by using serialEvent to listen command. If command is “gene”, Arduino will send 2 parameters tempe_data and humid_data with JSON format. The reason to random generate 2 parameters is I am too lazy to connect the DHT22.

test_serialport_b.ino


/*
 * Date: Mon, 12/06/2017
 * Desc: Arduino and NodeJS serialport
 * Info: Random generator temperature and humidity
 * to simulate DHT22, JSON format
 * only response data when receive request
 */
// used for generating data
double tempe_data;
double humid_data;
// used for serial buffering
#define TERM_CHAR '\n'
#define BUF_LEN 16
int i = 0;
char incomingChar; 
char buf[BUF_LEN];
// used pinLED for test mode
int pinLED = 13;

void setup() {
 delay(1000);
 // Initialize serial port
 Serial.begin(9600);
 //Serial.begin(115200);

// Initialize random generator
 randomSeed(analogRead(3)*1234);

// Initialize pinLED for test mode
 pinMode(pinLED, OUTPUT);
 digitalWrite(pinLED, LOW);
}

void loop() {
 // do nothing
}

double generate_data(long offset, long min_range, long max_range){
 // data = offset + rand, for example if range = [0,4] offset will be 2, rand will be 2
 long randParam = random(min_range*100, max_range*100);
 double data = (double)offset + (double)randParam/100;
 return data;
}

// generate random temperature and humidity
// send with JSON format
void procedure(){
 // generate
 tempe_data = generate_data(2, -2, 2);
 humid_data = generate_data(3, -3, 3);
 // send
 Serial.print(F("{\"CH1\": "));
 Serial.print(tempe_data);
 // create a fake CH2 to test JSON
 Serial.print(F(", \"CH2\": "));
 Serial.print(humid_data);
 Serial.println(F("}"));
}

void serialEvent() {
 // when characters arrive over the serial port...
 if (Serial.available()) {
 // wait a bit for the entire message to arrive
 delay(100);
 // clean buffer and index
 memset(buf,'\0',BUF_LEN); 
 i = 0; 
 // read all the available characters
 while (Serial.available() > 0) {
 incomingChar = (char) Serial.read();
 if(incomingChar != TERM_CHAR && i != BUF_LEN) 
 buf[i++] = incomingChar;
 else
 break;
 delay(1); // wait for another byte 
 }
 // Activate function on right code
 if(String(buf) == "10"){
 digitalWrite(pinLED, HIGH);
 } else if(String(buf) == "20"){
 digitalWrite(pinLED, LOW);
 } else if(String(buf) == "gene"){
 procedure();
 } else{
 // to be continued
 } 
 }
}

If you ask what is the role of pinLED and command "10" and "20", it is for testing. What is the character 'F' in Serial.print(F("{\"CH1\": "))? It is saving buffering bytes for transmitting serial data. What is the flaw of the code? It still does not make Arduino sleep and wake up.

About NodeJS role, I use express, socket.io and ejs to make a web server. I use serialport to receive and transmit data. I use chart.js to plot the data. What is the flaw of the code? The DAQ only happens in my PC, it cannot be accessed by another PC or my smartphone. Here comes the code

index.js


var express = require("express");
var app = express();
app.use(express.static("public"));
app.set("view engine", "ejs");
app.set("views", "./views");

var server = require("http").Server(app);
var io = require("socket.io")(server);
server.listen(3000);

// Using serialport to communicate with COM3
var serialport = require("serialport");
var mySerial = new serialport("COM3", {
 baudrate: 9600,
 parser: serialport.parsers.readline("\n")
});

mySerial.on("open", function(){
 console.log("COM3 is opened.");
});
// close serialport
mySerial.on("close", function(){
 console.log("COM3 is closed.");
});
// listening data on CH1
mySerial.on("data", function(JSON_data){
 // var CH1_data = JSON.parse(JSON_data).CH1;
 // var CH2_data = JSON.parse(JSON_data).CH2;
 // console.log(CH1_data + "----" + CH2_data);
 // sending COM data to client
 // io.sockets.emit("com-data",CH1_data);
 io.sockets.emit("com-data",JSON_data);
});

// Host server// SocketIO listening for connection and disconnection
io.on("connection", function(socket){
 console.log("Connecting client id: " + socket.id);
 socket.on("disconnect", function(){
 console.log("Client id: " + socket.id + " has disconnected");
 });
});

// Service for loading
app.get("/", function(req, res){
 res.render("trangchu");
});

// Testing serialport transmit every 2 seconds
var auto_counter = 0;
setInterval(function(){
 console.log(auto_counter);
 //mySerial.write(String(auto_counter));
 mySerial.write("gene");
 mySerial.write("\n"); // Eliminate
 auto_counter++;
 if(auto_counter == 21){
 auto_counter = 0;
 }
},2000);

trangchu.ejs


<html>
<head>
<title>COM data</title>

http://jquery.js
http://socket.io/socket.io.js
http://js/Chart.js
http://js/Chart.min.js

</head>

<body>
COM3. This is my localhost 192.168.1.101:3000

<h2 id="noidung"></h2>
 
</body> //Chart.defaults.global.responsive = true; //var ctx = document.getElementById("myChart"); var ctx = document.getElementById("myChart"); var counter; var myLineChart; createGraph() //--- declare function function createGraph(){ counter = 0; myLineChart = new Chart(ctx, { type: 'line', data: { labels: [], datasets: [{ label: ['Temperature'], data: [], backgroundColor: [ 'rgba(255, 99, 132, 0.2)' ], borderColor: [ 'rgba(255,99,132,1)' ], borderWidth: 1 }, { label: ['Humidity'], data: [], backgroundColor: [ 'rgba(54, 162, 235, 0.2)' ], borderColor: [ 'rgba(54, 162, 235, 1)' ], borderWidth: 1 }] }, options: { animation: { duration: 0, // general animation time }, scales: { yAxes: [{ ticks: { max: 6, beginAtZero:true }, stacked: false }] }, elements: { line: { tension: 0, // disables bezier curves } } } }); } // goi dien len server var socket = io("http://localhost:3000"); // client listening socket.on("com-data", function(data){ // $("#noidung").html(data); // console.log(counter + "-----" + data); var obj = JSON.parse(data); $("#noidung").html(obj.CH1 + " ----- " + obj.CH2); console.log(counter + "-----" + obj.CH1); counter++; myLineChart.data.labels.push(counter); myLineChart.data.datasets[0].data.push(obj.CH1); myLineChart.data.datasets[1].data.push(obj.CH2); myLineChart.update(); if(counter > 10){ myLineChart.destroy(); //counter = 0; createGraph(); } // if(counter = 20){ // counter = 0; // myLineChart.destroy(); // } else{ // counter++; // myLineChart.data.labels.push(counter); // myLineChart.data.datasets[0].data.push(data); // myLineChart.update(); // } }); $(document).ready(function(){ }); </html>

To use chart.js, in the folder public there will be a folder called js containing Chart.js and Chart.min.js (Chart will capital C). Note that I used COM3

Connect Arduino with loaded program and node index.js, you will see the result:

DAQ_nodejs

There is still some residual in my code. OK my bad. I am too lazy to delete the residual.

The biggest question in my head now is how to publish it globally so that everyone can see the chart of random generated parameters? I think about mongoDB and Heroku may work.

See you.

LCD I2C Firmata, johnny-five and NodeJS

This tutorial will show you how directly control Arduino via Firmata, NodeJS (as a server) and library johnny-five.
Step 1: load Firmata into Arduino Uno

Examples –> Firmata –> StandardFirmate –> Upload

Step 2: create a folder johnny_i2c on your desktop (you have to install NodeJS first)

cmd –> change directory to folder johnny_i2c

npm init –> Enter all and type yes at the last row

npm install johnny-five

create a file name index.js in the folder johnny_i2c with content

index.js


var five = require("johnny-five");
var board = new five.Board();

board.on("ready", function() {


 var random = Math.random().toString(36).replace(/[^a-z]+/g, "").substr(0, 4).toUpperCase();


 // Controller: PCF8574A (Generic I2C)
 // Locate the controller chip model number on the chip itself.
 var l = new five.LCD({
 controller: "PCF8574A"
 });
 
 l.clear();
 l.useChar("heart"); // use symbol of heart
 l.cursor(0, 0).print("hello world I2C");
 l.cursor(1, 0).print("use PCF8574A :heart:");
 l.cursor(1, 16).blink(); // hide the cursor

// no need to Ctrl+C
 setTimeout(function() {
 process.exit(0);
 }, 3000);
});

Step 3: run program (Command Prompt) node index.js

 

PS:

Use controller PCF8574A. Cannot use controller PCF8574

nRF24L01 with interrupt on receiver

I copied from Mr.ForceTronics with some modify, you can check these URL for reference:

youtube: https://www.youtube.com/watch?v=vzWcBAWpTx0

code: http://forcetronic.blogspot.com/2016/07/using-nrf24l01s-irq-pin-to-generate.html

You only act on response. That is the reason why interrupt is useful. The rest time you can rest to save time. On transmitter module, I send one byte of random number. On receiver module, I deploy pin IRQ to trigger interrupt on pin 3.

 nRF24L01_TX_test_c.ino


//********************Transmitter code**************************** 
#include <SPI.h> //Call SPI library so you can communicate with the nRF24L01+
#include <nRF24L01.h> //nRF2401 libarary found at https://github.com/tmrh20/RF24/
#include <RF24.h> //nRF2401 libarary found at https://github.com/tmrh20/RF24/

const int pinCE = 9; //This pin is used to set the nRF24 to standby (0) or active mode (1)
const int pinCSN = 10; //This pin is used to tell the nRF24 whether the SPI communication is a command or message to send out
byte counter = 1; //used to count the packets sent
RF24 wirelessSPI(pinCE, pinCSN); // Create your nRF24 object or wireless SPI connection
const uint64_t pAddress = 0xB00B1E5000LL; // Radio pipe addresses for the 2 nodes to communicate.

void setup() 
{
 Serial.begin(57600); //start serial to communicate process
 wirelessSPI.begin(); //Start the nRF24 module
 wirelessSPI.setAutoAck(1); // Ensure autoACK is enabled so rec sends ack packet to let you know it got the transmit packet payload
 wirelessSPI.enableAckPayload(); // Allow optional ack payloads
 wirelessSPI.setPALevel(RF24_PA_LOW);
 wirelessSPI.openWritingPipe(pAddress); // pipe address that we will communicate over, must be the same for each nRF24 module
 wirelessSPI.stopListening(); //transmitter so stop listening for data
 randomSeed(analogRead(0)); //use random ADC value to seed random number algorithm
}

void loop() {
 delay(random(100,5000)); //Generate delay time between 100msec and 5 sec
 long randNumber = random(0, 255);
 counter = byte(randNumber);
 Serial.println("Sending packet"); 
 if (!wirelessSPI.write( &counter, 1 )){ //if the send fails let the user know over serial monitor
 Serial.println("packet delivery failed"); 
 }
 Serial.println(); 
}

 nRF24L01_RX_test_c.ino


#include <SPI.h> //Call SPI library so you can communicate with the nRF24L01+
#include <nRF24L01.h> //nRF2401 libarary found at https://github.com/tmrh20/RF24/
#include <RF24.h> //nRF2401 libarary found at https://github.com/tmrh20/RF24/
#include <avr/sleep.h> //library needed to use AVR based sleep API

const int pinCE = 9; //This pin is used to set the nRF24 to standby (0) or active mode (1)
const int pinCSN = 10; //This pin is used to tell the nRF24 whether the SPI communication is a command or message to send out
byte gotByte = 0; //used to store payload from transmit module
volatile int count = 0; //tracks the number of interrupts from IRQ
int pCount = 0; //tracks what last count value was so know when count has been updated
RF24 wirelessSPI(pinCE, pinCSN); // Declare object from nRF24 library (Create your wireless SPI) 
const uint64_t pAddress = 0xB00B1E5000LL; //Create a pipe addresses for the 2 nodes to communicate over, the "LL" is for LongLong type

void setup() {
 wirelessSPI.begin(); //Start the nRF24 module
 wirelessSPI.setAutoAck(1); // Ensure autoACK is enabled so rec sends ack packet to let you know it got the transmit packet payload
 wirelessSPI.enableAckPayload(); //allows you to include payload on ack packet
 wirelessSPI.maskIRQ(1,1,0); //mask all IRQ triggers except for receive (1 is mask, 0 is no mask)
 wirelessSPI.setPALevel(RF24_PA_LOW); //Set power level to low, won't work well at higher levels (interfer with receiver)
 wirelessSPI.openReadingPipe(1,pAddress); //open pipe o for recieving meassages with pipe address
 wirelessSPI.startListening(); // Start listening for messages
 attachInterrupt(1, interruptFunction, FALLING); //Create interrupt: 0 for pin 2 or 1 for pin 3, the name of the interrupt function or ISR, and condition to trigger interrupt
}

void loop() {

if(pCount < count) { //If this is true it means count was interated and another interrupt occurred
 Serial.begin(57600); //start serial to communicate process
 Serial.print("Receive packet number ");
 Serial.print(count); 
 Serial.print(" has content: ");
 Serial.println(gotByte);
 Serial.end(); //have to end serial since it uses interrupts
 pCount = count; 
 }
}

//This is the function called when the interrupt occurs (pin 2 goes high)
//this is often referred to as the interrupt service routine or ISR
//This cannot take any input arguments or return anything
void interruptFunction() {
 count++; //up the receive counter
 while(wirelessSPI.available()) { //get data sent from transmit
 wirelessSPI.read( &gotByte, 1 ); //read one byte of data and store it in gotByte variable
 }
}

Actually it is one-part done while we have total 2 modules here. The transmitter has to send the message all the time while the receiver only works when interrupt is triggered. The ideal is when the receiver makes a request to the transmitter, the transmitter then sends the message. The definition of transmitter and receiver is no longer suitable. The new definition is requester and responser.

 

I am so lazy at this weekend. Maybe nextweek I will be better. I really need a good sleep.

Rotary encoder used as infinite volume knob

I copied this code from Mr.Ralph S Bacon with these URL:
youtube: https://www.youtube.com/watch?v=J9cDEef0IbQ

code: https://dl.dropboxusercontent.com/u/20622434/RotaryEncoderInterrruptsLED.ino

The good thing of this code is using interrupt on pin3. The bad things is that I modified PinLED from pin 11 to pin 13 and it did not change the brightness of the PinLED.

The hardware connection has a note: Vcc –> 3.3V, CLK –> pin3, DT –> pin4, SW –> pin8. The range value will be [0, 100]


// Used for generating interrupts using CLK signal
const int PinA = 3;

// Used for reading DT signal
const int PinB = 4;

// Used for the push button switch
const int PinSW = 8;

// Simple PWM LED pin
#define PinLED 13

// Keep track of last rotary value
int lastCount = 50;

// Updated by the ISR (Interrupt Service Routine)
volatile int virtualPosition = 50;

// ------------------------------------------------------------------
// INTERRUPT INTERRUPT INTERRUPT INTERRUPT INTERRUPT 
// ------------------------------------------------------------------
void isr () {
 static unsigned long lastInterruptTime = 0;
 unsigned long interruptTime = millis();

// If interrupts come faster than 5ms, assume it's a bounce and ignore
 if (interruptTime - lastInterruptTime > 5) {
 if (digitalRead(PinB) == LOW)
 {
 virtualPosition-- ; // Could be -5 or -10
 }
 else {
 virtualPosition++ ; // Could be +5 or +10
 }

// Restrict value from 0 to +100
 virtualPosition = min(100, max(0, virtualPosition));

// Keep track of when we were here last (no more than every 5ms)
 lastInterruptTime = interruptTime;
 }
}

// ------------------------------------------------------------------
// SETUP SETUP SETUP SETUP SETUP SETUP SETUP 
// ------------------------------------------------------------------
void setup() {
 // Just whilst we debug, view output on serial monitor
 Serial.begin(9600);

// Rotary pulses are INPUTs
 pinMode(PinA, INPUT);
 pinMode(PinB, INPUT);
 pinMode(PinLED, OUTPUT);
 analogWrite(PinLED, virtualPosition);

// Switch is floating so use the in-built PULLUP so we don't need a resistor
 pinMode(PinSW, INPUT_PULLUP);

// Attach the routine to service the interrupts
 attachInterrupt(digitalPinToInterrupt(PinA), isr, LOW);

// Ready to go!
 Serial.println("Start");
}

// ------------------------------------------------------------------
// MAIN LOOP MAIN LOOP MAIN LOOP MAIN LOOP MAIN LOOP
// ------------------------------------------------------------------
void loop() {

// Is someone pressing the rotary switch?
 if ((!digitalRead(PinSW))) {
 virtualPosition = 50;
 while (!digitalRead(PinSW))
 delay(10);
 Serial.println("Reset");
 }

// If the current rotary switch position has changed then update everything
 if (virtualPosition != lastCount) {
 
 // Our LED gets brighter or dimmer
 analogWrite(PinLED, virtualPosition);

// Write out to serial monitor the value and direction
 Serial.print(virtualPosition > lastCount ? "Up :" : "Down:");
 Serial.println(virtualPosition);

// Keep track of this new value
 lastCount = virtualPosition ;
 }
}

 

[PA-03c] Read temperature DHT21 with Qt

Another useful code from Vannevar Morgan, you can check these out:
youtube: https://www.youtube.com/watch?v=1PNn63P793Y

github: https://github.com/vannevar-morgan/Qt-Temperature-Sensor

However, I do not use the temperature DS18B20. I use temperature and humidity DHT21. And in Qt code, I use Celcius degree instead of Fahrenheit degree. In Arduino code, I use header file floatToString to display the data to LCD.

 pyqt_dht.ino


/*
 * Date: Wed, 10/05/2017
 * Desc: Read Temperature and Humidity from DHT21
 * Display on LCD
 * Send to PC via serial
 */
#include <Wire.h>
#include <LCD.h>
#include <LiquidCrystal_I2C.h>
#include "DHT.h"
#include "floatToString.h"

#define I2C_ADDR 0x3F 
#define BACKLIGHT_PIN 3
#define En_pin 2
#define Rw_pin 1
#define Rs_pin 0
#define D4_pin 4
#define D5_pin 5
#define D6_pin 6
#define D7_pin 7
LiquidCrystal_I2C lcd(I2C_ADDR,En_pin,Rw_pin,Rs_pin,D4_pin,D5_pin,D6_pin,D7_pin);

#define DHTPIN 9
#define DHTTYPE DHT21
DHT dht(DHTPIN, DHTTYPE);
float t;
float h;
char bufferstore[20]; // used by floatToString to display on LCD

void setup() {
 delay(1000);
 // Initialize Serial
 Serial.begin(9600); 
 // Initialize DHT
 dht.begin();

// Initialize LCD
 lcd.begin(16,2);
 lcd.setBacklightPin(BACKLIGHT_PIN,POSITIVE);
 lcd.setBacklight(HIGH); 
}

void loop() {
 // Read sensor parameter
 h = dht.readHumidity();
 t = dht.readTemperature();
 // Display on LCD
 lcd_display_temp_humid(t,h);
 // Send via serialport
 Serial.print(t);
 Serial.print(",");
 Serial.flush();
 // Delay for next round
 delay(2000);
}

void lcd_display_temp_humid(float temperature, float humidity){
 lcd.clear();
 lcd.print("Tempe: ");
 lcd.print(floatToString(bufferstore, temperature, 2, 5, true));
 lcd.print(" C");
 lcd.setCursor(0,1);
 lcd.print("Humid: ");
 lcd.print(floatToString(bufferstore, humidity, 2, 5, true));
 lcd.print(" %");
}

floatToString.h


// floatToString.h
//
// Tim Hirzel
// tim@growdown.com
// March 2008
// float to string
// 
// If you don't save this as a .h, you will want to remove the default arguments 
// uncomment this first line, and swap it for the next. I don't think keyword arguments compile in .pde files

//char * floatToString(char * outstr, float value, int places, int minwidth=, bool rightjustify) {
char * floatToString(char * outstr, float value, int places, int minwidth=0, bool rightjustify=false) {
 // this is used to write a float value to string, outstr. oustr is also the return value.
 int digit;
 float tens = 0.1;
 int tenscount = 0;
 int i;
 float tempfloat = value;
 int c = 0;
 int charcount = 1;
 int extra = 0;
 // make sure we round properly. this could use pow from <math.h>, but doesn't seem worth the import
 // if this rounding step isn't here, the value 54.321 prints as 54.3209

// calculate rounding term d: 0.5/pow(10,places) 
 float d = 0.5;
 if (value < 0)
 d *= -1.0;
 // divide by ten for each decimal place
 for (i = 0; i < places; i++)
 d/= 10.0; 
 // this small addition, combined with truncation will round our values properly 
 tempfloat += d;

// first get value tens to be the large power of ten less than value 
 if (value < 0)
 tempfloat *= -1.0;
 while ((tens * 10.0) <= tempfloat) {
 tens *= 10.0;
 tenscount += 1;
 }

if (tenscount > 0)
 charcount += tenscount;
 else
 charcount += 1;

if (value < 0)
 charcount += 1;
 charcount += 1 + places;

minwidth += 1; // both count the null final character
 if (minwidth > charcount){ 
 extra = minwidth - charcount;
 charcount = minwidth;
 }

if (extra > 0 and rightjustify) {
 for (int i = 0; i< extra; i++) {
 outstr[c++] = ' ';
 }
 }

// write out the negative if needed
 if (value < 0)
 outstr[c++] = '-';

if (tenscount == 0) 
 outstr[c++] = '0';

for (i=0; i< tenscount; i++) {
 digit = (int) (tempfloat/tens);
 itoa(digit, &outstr[c++], 10);
 tempfloat = tempfloat - ((float)digit * tens);
 tens /= 10.0;
 }

// if no places after decimal, stop now and return

// otherwise, write the point and continue on
 if (places > 0)
 outstr[c++] = '.';


 // now write out each decimal place by shifting digits one by one into the ones place and writing the truncated value
 for (i = 0; i < places; i++) {
 tempfloat *= 10.0; 
 digit = (int) tempfloat;
 itoa(digit, &outstr[c++], 10);
 // once written, subtract off that digit
 tempfloat = tempfloat - (float) digit; 
 }
 if (extra > 0 and not rightjustify) {
 for (int i = 0; i< extra; i++) {
 outstr[c++] = ' ';
 }
 }


 outstr[c++] = '\0';
 return outstr;
}

Till now, I am just a copier without clearly understand how things are done. I have temperature and humidity but only show one of them. The main loop of Arduino has to send the data continuously. It is not practical. The right procedure is when PC sends command to Arduino, Arduino responses. I hope to do better job next time.

PS: remember 10k pick-up resistor of DHT signal pin.